/\* Project Title: Proc Report Example

Requesting Department: Internal

Requestor: XXXXXXXXXX

Origination Date: 9/19/2023

Requested Completion Date: 9/29/2023

Date received: 9/19/2023

Assigned Priority: High

Assigned Delivery Date: 9/29/2023

RDA\_Project\_number: XXXXXXXXXX

Assigned Analyst: Meagan Windler

Assigned Days: 2

Support Analyst:

Perc\_Support:

Assigned Completion Date: 9/29/2023

Remarks: All pharmacy fills during 1st quarter of 2023. Summary on one tab broken out by

Company and network (Ascension St. John, Saint Francis, Other) and fill month.

Claim Detail on another tab. Include Women's health.

For summary tab include – Month, Company Network, # of scripts, total days supply,

Member Pay, CCOK Pay, and Total Allow

For detail tab include – Company, Network, claim number, member number, fill date,

days supply, dispensed quantity, ndc,\*/

/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

/\*\*\*\*\* Setup \*\*\*\*\*/

/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

/\* Clearing Work Library \*/

Proc Datasets nolist nodetails lib=Work kill;

Quit;

%Let Root = XXXXXXXXXX;

%Let Outpath=&Root\\HDA\RDA\mwindler\Proc Report Example\Output;

%Let analyst=MW;

%Let rda=XXXXXXXXXX;

%Let RprtDate = %Sysfunc(PutN(%Sysfunc(Today()),yymmddn8)) ;

%Let RunDate = %Sysfunc(PutN(%Sysfunc(Today()),mmddyys10)) ;

%Let SASAutos = &Root\HDA\Resources\SAS\_Macros ;

Options SASAutos = (SASAutos,"&SASAutos") ;

Options XSync NoXWait MAUTOSOURCE ;

Option FmtSearch = (Work Formats) ;

/\*Timeframe for services\*/

%Let period\_start = '01JAN2023'd;

%Let period\_end = '31MAR2023'd;

/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

/\*\*\*\*\* Pharmacy Data Pull \*\*\*\*\*/

/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

\*Establish variables for quicker data pulls;

%Let fill\_vars=

buss\_carr mbr\_rgn rxclm rxclm\_seq rev\_paid\_flg mbr\_id date\_fill

day\_sup disp\_quant ndc amt\_mbr\_pay amt\_paid amt\_tot;

%Let Network\_SF='XXXXXXXXXX';

%Let Network\_ASJ='XXXXXXXXXX','XXXXXXXXXX','XXXXXXXXXX';

\*Data pull from CVSDATA.CVSRXDATA;

Data q1fills;

Format buss\_carr mbr\_rgn rxclm rxclm\_seq rev\_paid\_flg mbr\_id

date\_fill day\_sup disp\_quant ndc amt\_mbr\_pay amt\_paid amt\_tot;

Set cvsdata.cvsrxdata (Keep=&fill\_vars);

Where &period\_start <= date\_fill <= &period\_end; Run;

\*Data pull from CVSDATA.CVSWH for women's health fills;

Data q1fills\_wh;

Format buss\_carr mbr\_rgn rxclm rxclm\_seq rev\_paid\_flg mbr\_id

date\_fill day\_sup disp\_quant ndc amt\_mbr\_pay amt\_paid amt\_tot;

Set cvsdata.cvswh (Keep=&fill\_vars);

Where &period\_start <= date\_fill <= &period\_end; Run;

\*Merge the two pharm pulls;

Data q1fills\_merged;

Set q1fills q1fills\_wh; Run;

\*Select only paid claims;

Proc Sort Data=q1fills\_merged;

By rxclm Descending rxclm\_seq Descending rev\_paid\_flg; Run;

Data paid\_q1fills;

Set q1fills\_merged;

By rxclm;

If last.rxclm and rev\_paid\_flg > 0; Run;

\*Adding company, network, and month\_fill to dataset;

Data q1fills\_2;

Set paid\_q1fills;

bus\_unit=substr(buss\_carr,1,2);

If bus\_unit = 'XXXXXXXXXX' then Company="CommunityCare XXXXXXXXXX";

Else if bus\_unit = 'XXXXXXXXXX' then Company='CommunityCare XXXXXXXXXX';

Else if bus\_unit in ('XXXXXXXXXX', 'XXXXXXXXXX') then Company='CommunityCareXXXXXXXXXX';

Else if bus\_unit = 'XXXXXXXXXX' then Company='CommunityCare XXXXXXXXXX';

Else if buss\_carr = 'XXXXXXXXXX' then Company='CommunityCare XXXXXXXXXX';

If mbr\_rgn in (&Network\_ASJ) then network = 'XXXXXXXXXX';

else if mbr\_rgn in (&Network\_SF) then network = 'XXXXXXXXXX';

else network = 'Other';

month\_fill=Month(date\_fill); Run;

\*Creating dataset for summary tab;

Data summary;

Set q1fills\_2 (Keep=company network month\_fill day\_sup amt\_mbr\_pay amt\_paid amt\_tot);

Fill\_count= 1;

Run;

\* Summarize claims by company, network, and fill month;

Proc Summary Data=summary nway missing;

Class month\_fill company network;

Var fill\_count day\_sup amt\_mbr\_pay amt\_paid amt\_tot;

output out=q1fills\_summary sum=; Run;

Data q1fills\_summary\_2 (Drop=\_type\_ \_freq\_);

Set q1fills\_summary; Run;

Data q1fills\_summary\_3;

Set q1fills\_summary\_2;

fill\_month = mdy(month\_fill, 1, 2023);

Format fill\_month monyy7.; Run;

\*Detail report dataset;

Data q1fills\_detail;

Set q1fills\_2 (Keep=Company network rxclm mbr\_id date\_fill day\_sup disp\_quant ndc);

fill\_date = put(date\_fill, mmddyy10.);Run;

/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

/\*\*\*\*\* Macro Reports \*\*\*\*\*/

/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

\*Macro for q1 fill summary tab;

%Macro RprtQ1FillSummary();

Title;

%Let Title1 = Pharmacy Fills for Q1 2023;

%Let Title2 = Summary By Company, Network, and Month;

Footnote;

Proc Report Data = q1fills\_summary\_3 nowindows missing

Style(Header) = {VerticalAlign = middle}

Style(Column) = {FontFamily = "Trebuchet MS" FontSize = 12pt};

Title1 j = l Height = 14pt Font = "Trebuchet MS" Bold Color = Black " &Title1";

Title2 j = l Height = 13pt Font = "Trebuchet MS" Bold Color = '#808080' " &Title2";

Column fill\_month Company network fill\_count day\_sup amt\_mbr\_pay amt\_paid amt\_tot;

Define fill\_month/Group 'Fill Month' order=data Style(column)=data[width=1000% tagattr='wrap:yes'];

Define company/Group 'Company' Style(column)=data[width=1000% tagattr='wrap:yes'];

Define network/Group 'Network' Style(column)=data[width=1000% tagattr='wrap:yes'];

Define fill\_count/Analysis 'Total Scripts' Style(column)=data[width=1000% tagattr='wrap:yes'];

Define day\_sup/Analysis 'Total Days Supply' Style(column)=data[width=1000% tagattr='wrap:yes'];

Define amt\_mbr\_pay/Analysis 'Total Member Pay' Style(column)=data[width=1000% tagattr='wrap:yes'];

Define amt\_paid/Analysis 'Total CCOK Pay' Style(column)=data[width=1000% tagattr='wrap:yes'];

Define amt\_tot/Analysis 'Total Allow Amount' Style(column)=data[width=1000% tagattr='wrap:yes'];

Break After fill\_month / Summarize Style = {Background = #C8C8C8 Foreground = Black Font = ('Trebuchet MS',12pt,bold)};

Compute Before fill\_month;

network='Subtotal'; Endcomp;

RBreak After / Summarize Style = {Background = #DBF5DC Foreground = Black Font = ('Trebuchet MS',12pt,bold)};

Compute after ;

network='Grand Total'; Endcomp;

Run; %Mend;

\*Macro pharmacy fill detail tab;

%Macro RprtQ1FillsDetails();

Title;

%Let Title1 = Pharmacy Fills for Q1 2023;

%Let Title2 = Detail Page;

Footnote;

Proc Report Data = q1fills\_detail nowindows missing

Style(Header) = {VerticalAlign = middle}

Style(Column) = {FontFamily = "Trebuchet MS" FontSize = 12pt};

Title1 j = l Height = 14pt Font = "Trebuchet MS" Bold Color = Black " &Title1";

Title2 j = l Height = 13pt Font = "Trebuchet MS" Bold Color = '#808080' " &Title2";

Column Company network rxclm mbr\_id fill\_date day\_sup disp\_quant ndc;

Define Company/Display 'Company';

Define network/Display 'Network';

Define rxclm/Display 'Claim Number';

Define mbr\_id/Display 'Member Number';

Define fill\_date/Display 'Fill Date';

Define day\_sup/Display 'Days Supply';

Define disp\_quant/Display 'Dispensed Quantity';

Define ndc/Display 'National Drug Code';

Run ; %Mend ;

/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

/\*\*\*\*\* Exporting Data \*\*\*\*\*/

/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

%Let RprtFileName = Pharmacy Training Assignment;

%Let PartOneWidths = 20, 20, 20, 20, 20, 20, 20;

%Let PartTwoWidths = 20, 20, 20, 20, 20, 20, 20, 20;

Options topmargin = .5in

bottommargin = .7in

leftmargin = .25in

rightmargin = .25in ;

ODS Path(Prepend) Work.Template(Update) ;

Proc Template ;

Define Style SummaryReport ;

Parent = Styles.Excel ;

Class Body /

BackGroundColor = White

FontFamily = "Trebuchet MS"

Fontsize = 12pt

Color = Black

;

Class SystemTitle /

BackGroundColor = White

FontFamily = "Trebuchet MS"

FontWeight = Bold

;

Class SystemFooter /

BackGroundColor = White

FontFamily = "Trebuchet MS"

FontSize = 12pt

;

Style CellContents /

FontFamily = "Trebuchet MS"

FontSize = 12pt

Color = Black

;

Style Header /

BackGroundColor = cx007852

FontFamily = "Trebuchet MS"

FontSize = 12pt

FontWeight = Bold

Color = White

;

Style Table /

FontFamily = "Trebuchet MS"

FontSize = 12pt

Color = Black

;

End ; Run ;

ODS \_ALL\_ Close ;

ODS Excel File = "%SuperQ(OutPath)\&RprtFileName &RprtDate..xlsx"

Style = SummaryReport

Options(

Row\_Repeat = '10'

Frozen\_Headers = '10'

Print\_Footer = "%NRSTR(&L&11)&RDA - &Analyst %NRSTR(&C&11) Page %NRSTR(&P) of %NRSTR(&N) %NRSTR(&R&11) &rundate" /\* Standard by Department policy \*/

Print\_Footer\_Margin = '.25'

Embed\_Titles\_Once = 'On'

Embedded\_Titles = 'Yes'

Embedded\_Footnotes = 'Yes'

GridLines = 'Off'

Row\_Heights = '0,0,0,0,0,0,10'

Orientation = 'Landscape'

Center\_Horizontal = 'no'

FitToPage = 'yes'

Pages\_FitHeight = '9999'

Pages\_FitWidth = '1'

Flow = 'Text'

Suppress\_ByLines = 'ON'

Sheet\_Interval = 'None'

) ;

ODS Excel

Options(

Sheet\_Name = "Summary"

Absolute\_Column\_Width = "&PartOneWidths") ;

Proc GOptions ;/\* Add logo \*/

Title ;

Footnote ;

GOptions iback = "&Root\HDA\Resources\Logos\Community Care Logo 856x282.jpg"

ImageStyle = Fit VSize = 0.8in HSize = 1.85in ; Run ;

Proc GSlide ; Run ;

%RprtQ1FillSummary; /\* Call Proc Report \*/

/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

/\*\*\*\*\* Exporting Detail Data \*\*\*\*\*/

/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

/\*Exporting detail data using ODS Tag Sets as it times out via ODS Excel\*/

ods results=off;

ods tagsets.excelxp file="&Outpath\Pharmacy Training.xml"

/\* Conforming to CCOK Communication Guidelines \*/

style = SaswebCCOKcg

options(

embedded\_titles = 'yes'

embedded\_footnotes = 'yes'

row\_repeat = "5"

frozen\_headers = '4'

print\_footer = "%NRSTR(&L&11)&RDA - &analyst %NRSTR(&C&11) %NRSTR(&r&11)"

page\_order\_across = 'yes'

center\_horizontal = 'yes'

gridlines = 'yes'

fittopage = 'yes'

pages\_fitwidth = '1'

pages\_fitheight = '1000'

orientation = 'portrait'

autofit\_height = 'yes'

sheet\_interval = 'proc'

zoom = "80"

absolute\_column\_width = '20,20,20,20,20');

/\* Defining Sheet Name for Export \*/

ods tagsets.Excelxp options(sheet\_name="Details");

/\* Addding titles and footnotes \*/

Title1 "Pharmacy Fills for Q1 2023";

Title2 "Detail Page";

%RprtQ1FillsDetails() ;

title;

title2;

/\* Closing ODS Excel \*/

ods tagsets.excelxp close;

ods results=on;

%XMLtoXLSX (&OutPath ,

%quote(Pharmacy Training) ,

1 ) ;